camera/hal/mediatek/mtkcam/utils/metastore/BUILD.gn

# Copyright 2019 The Chromium OS Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

action("gen_config_metadata") {
  script = "run_script.py"
  outputs = [ "$target_gen_dir/custgen.config_static.h" ]
  args = [
    rebase_path("./metadataprovider/custom/gen_config_metadata.sh",
                root_build_dir),
    "${sysroot}/usr/include/cros-camera/custom/imgsensor_metadata",
    "${target_gen_dir}",
  ]
}

action("gen_request_metadata") {
  script = "run_script.py"
  outputs = [ "$target_gen_dir/custgen.config_request.h" ]
  args = [
    rebase_path("./templateRequest/custom/gen_request_metadata.sh",
                root_build_dir),
    "${sysroot}/usr/include/cros-camera/custom/imgsensor_metadata",
    "${target_gen_dir}",
  ]
}

shared_library("libmtkcam_metastore") {
  import("//camera/hal/mediatek/common-config.gni")
  sources = [
    "metadataprovider/MetadataProvider.cpp",
    "metadataprovider/MetadataProviderManager.cpp",
    "metadataprovider/constructStaticMetadata.cpp",
    "metadataprovider/custom/custom.cpp",
    "templateRequest/TemplateRequest.cpp",
    "templateRequest/TemplateRequestManager.cpp",
    "templateRequest/custom/custom.cpp",
  ]
  include_dirs += [
    ".",
    "${mtk_root_path}/mtkcam/custom",
    "${mtk_root_path}/mtkcam/custom/common/hal/inc",
    "${mtk_root_path}/mtkcam/custom/mt8183",
    "${mtk_root_path}/mtkcam/custom/mt8183/hal/inc",
    "${mtk_root_path}/mtkcam/custom/mt8183/kernel/imgsensor",
    "${mtk_root_path}/mtkcam/utils/metastore/metadataprovider",
    "${mtk_root_path}/mtkcam/utils/metastore/templateRequest",
    "${target_gen_dir}",
  ]
  libs += [
    "dl",
    "pthread",
    "camera_metadata",
  ]
  defines += [ "NR3D_SUPPORTED" ]
  deps += [
    ":gen_config_metadata",
    ":gen_request_metadata",
    "//camera/hal/mediatek/mtkcam/utils/TuningUtils:libmtkcam_tuning_utils",
    "//camera/hal/mediatek/mtkcam/utils/metadata:libmtkcam_metadata",
    "//camera/hal/mediatek/mtkcam/utils/module:libmtkcam_modulehelper",
    "//camera/hal/mediatek/mtkcam/utils/property_service:libmtk_property",
  ]
}