| # Copyright 1999-2011 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Header: /var/cvsroot/gentoo-x86/sys-devel/autoconf/autoconf-2.68.ebuild,v 1.9 2011/07/22 13:51:13 jer Exp $ |
| |
| EAPI="2" |
| |
| if [[ ${PV} == "9999" ]] ; then |
| EGIT_REPO_URI="git://git.savannah.gnu.org/autoconf.git" |
| inherit git |
| SRC_URI="" |
| #KEYWORDS="" |
| else |
| SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2 |
| ftp://alpha.gnu.org/pub/gnu/${PN}/${P}.tar.bz2" |
| KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~sparc-fbsd ~x86-fbsd" |
| fi |
| |
| DESCRIPTION="Used to create autoconfiguration files" |
| HOMEPAGE="http://www.gnu.org/software/autoconf/autoconf.html" |
| |
| LICENSE="GPL-3" |
| SLOT="2.5" |
| IUSE="emacs" |
| |
| DEPEND=">=sys-apps/texinfo-4.3 |
| >=sys-devel/m4-1.4.6 |
| dev-lang/perl" |
| RDEPEND="${DEPEND} |
| >=sys-devel/autoconf-wrapper-10" |
| PDEPEND="emacs? ( app-emacs/autoconf-mode )" |
| |
| src_prepare() { |
| if [[ ${PV} == "9999" ]] ; then |
| autoreconf -f -i || die |
| fi |
| } |
| |
| src_configure() { |
| # Disable Emacs in the build system since it is in a separate package. |
| export EMACS=no |
| econf --program-suffix="-${PV}" || die |
| # econf updates config.{sub,guess} which forces the manpages |
| # to be regenerated which we dont want to do #146621 |
| touch man/*.1 |
| } |
| |
| src_install() { |
| emake DESTDIR="${D}" install || die |
| dodoc AUTHORS BUGS NEWS README TODO THANKS \ |
| ChangeLog ChangeLog.0 ChangeLog.1 ChangeLog.2 |
| } |