| # Copyright 1999-2018 Gentoo Authors |
| # Distributed under the terms of the GNU General Public License v2 |
| |
| EAPI=6 |
| inherit bash-completion-r1 eutils multilib-minimal |
| |
| DESCRIPTION="D-Bus bindings for glib" |
| HOMEPAGE="https://dbus.freedesktop.org/" |
| SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz" |
| |
| LICENSE="|| ( GPL-2 AFL-2.1 )" |
| SLOT="0" |
| KEYWORDS="*" |
| IUSE="debug static-libs test" |
| |
| CDEPEND=" |
| >=dev-libs/expat-2.1.0-r3[${MULTILIB_USEDEP}] |
| >=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}] |
| >=sys-apps/dbus-1.8[${MULTILIB_USEDEP}] |
| " |
| DEPEND="${CDEPEND} |
| >=dev-util/glib-utils-2.40 |
| >=dev-util/gtk-doc-am-1.14 |
| virtual/pkgconfig |
| " |
| RDEPEND="${CDEPEND}" |
| |
| DOCS=( AUTHORS ChangeLog HACKING NEWS README ) |
| |
| set_TBD() { |
| # out of sources build dir for make check |
| export TBD="${BUILD_DIR}-tests" |
| } |
| |
| multilib_src_configure() { |
| local myconf=( |
| --localstatedir="${EPREFIX}"/var |
| --enable-bash-completion |
| --disable-gtk-doc |
| $(use_enable debug asserts) |
| $(use_enable static-libs static) |
| ) |
| |
| ECONF_SOURCE="${S}" econf "${myconf[@]}" |
| |
| ln -s "${S}"/doc/reference/html doc/reference/html || die #460042 |
| |
| if use test; then |
| set_TBD |
| mkdir "${TBD}" || die |
| cd "${TBD}" || die |
| einfo "Running configure in ${TBD}" |
| ECONF_SOURCE="${S}" econf \ |
| "${myconf[@]}" \ |
| $(use_enable test checks) \ |
| $(use_enable test tests) \ |
| $(use_enable test asserts) |
| fi |
| } |
| |
| multilib_src_compile() { |
| emake |
| |
| if use test; then |
| set_TBD |
| cd "${TBD}" || die |
| einfo "Running make in ${TBD}" |
| emake |
| fi |
| } |
| |
| multilib_src_test() { |
| set_TBD |
| cd "${TBD}" || die |
| emake check |
| } |
| |
| multilib_src_install_all() { |
| einstalldocs |
| |
| newbashcomp "${ED}"/etc/bash_completion.d/dbus-bash-completion.sh dbus-send |
| rm -rf "${ED}"/etc/bash_completion.d || die |
| |
| prune_libtool_files |
| } |
