| # Copyright 1999-2013 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Header: /var/cvsroot/gentoo-x86/dev-lang/python-exec/python-exec-0.3.1.ebuild,v 1.2 2013/11/15 22:12:48 robbat2 Exp $ |
| |
| EAPI=5 |
| |
| # Kids, don't do this at home! |
| inherit python-utils-r1 |
| PYTHON_COMPAT=( "${_PYTHON_ALL_IMPLS[@]}" ) |
| |
| inherit autotools-utils python-r1 |
| |
| DESCRIPTION="Python script wrapper" |
| HOMEPAGE="https://bitbucket.org/mgorny/python-exec/" |
| SRC_URI="mirror://bitbucket/mgorny/${PN}/downloads/${P}.tar.bz2" |
| |
| LICENSE="BSD" |
| SLOT="0" |
| KEYWORDS="alpha amd64 arm hppa ia64 ~m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris" |
| IUSE="" |
| |
| RDEPEND="!<dev-python/python-exec-10000" |
| PDEPEND=">=dev-python/python-exec-10000:$SLOT" |
| |
| src_configure() { |
| local pyimpls i EPYTHON |
| for i in "${PYTHON_COMPAT[@]}"; do |
| python_export "${i}" EPYTHON |
| pyimpls+=" ${EPYTHON}" |
| done |
| |
| local myeconfargs=( |
| --with-eprefix="${EPREFIX}" |
| --with-python-impls="${pyimpls}" |
| ) |
| |
| autotools-utils_src_configure |
| } |