| # Copyright 1999-2017 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| |
| EAPI="6" |
| |
| inherit toolchain-funcs |
| |
| MY_P="${P//_/-}" |
| MY_RELEASEDATE="20170804" |
| |
| SEPOL_VER="${PV}" |
| |
| DESCRIPTION="SELinux policy compiler" |
| HOMEPAGE="http://userspace.selinuxproject.org" |
| |
| if [[ ${PV} == 9999 ]] ; then |
| inherit git-r3 |
| EGIT_REPO_URI="https://github.com/SELinuxProject/selinux.git" |
| S="${WORKDIR}/${MY_P}/${PN}" |
| else |
| SRC_URI="https://raw.githubusercontent.com/wiki/SELinuxProject/selinux/files/releases/${MY_RELEASEDATE}/${MY_P}.tar.gz" |
| KEYWORDS="*" |
| S="${WORKDIR}/${MY_P}" |
| fi |
| |
| LICENSE="GPL-2" |
| SLOT="0" |
| IUSE="debug" |
| |
| DEPEND=">=sys-libs/libsepol-${SEPOL_VER} |
| sys-devel/flex |
| sys-devel/bison" |
| |
| src_compile() { |
| emake \ |
| CC="$(tc-getCC)" \ |
| YACC="bison -y" \ |
| LIBDIR="\$(PREFIX)/$(get_libdir)" |
| } |
| |
| src_install() { |
| emake DESTDIR="${D}" \ |
| LIBSEPOLA="/usr/$(get_libdir)/libsepol.a" \ |
| install |
| |
| if use debug; then |
| dobin "${S}/test/dismod" |
| dobin "${S}/test/dispol" |
| fi |
| } |
| |
| pkg_postinst() { |
| einfo "This checkpolicy can compile version `checkpolicy -V |cut -f 1 -d ' '` policy." |
| } |
