| # Copyright 1999-2014 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/libusb-1.0.18.ebuild,v 1.12 2014/03/24 17:51:41 ssuominen Exp $ |
| |
| EAPI=5 |
| inherit eutils toolchain-funcs multilib-minimal |
| |
| DESCRIPTION="Userspace access to USB devices" |
| HOMEPAGE="http://libusb.sourceforge.net/" |
| SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2" |
| |
| LICENSE="LGPL-2.1" |
| SLOT="1" |
| KEYWORDS="*" |
| IUSE="debug doc examples static-libs test udev" |
| |
| RDEPEND="udev? ( >=virtual/udev-200[${MULTILIB_USEDEP}] ) |
| abi_x86_32? ( |
| !<=app-emulation/emul-linux-x86-baselibs-20130224-r7 |
| !app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] |
| )" |
| DEPEND="${RDEPEND} |
| doc? ( app-doc/doxygen ) |
| !udev? ( virtual/os-headers )" |
| |
| multilib_src_configure() { |
| ECONF_SOURCE=${S} \ |
| econf \ |
| $(use_enable static-libs static) \ |
| $(use_enable udev) \ |
| $(use_enable debug debug-log) \ |
| $(use_enable test tests-build) |
| } |
| |
| multilib_src_compile() { |
| emake |
| |
| if multilib_is_native_abi; then |
| use doc && emake -C doc docs |
| fi |
| } |
| |
| multilib_src_test() { |
| emake check |
| |
| # noinst_PROGRAMS from tests/Makefile.am |
| tests/stress || die |
| } |
| |
| multilib_src_install() { |
| emake DESTDIR="${D}" install |
| |
| if multilib_is_native_abi; then |
| gen_usr_ldscript -a usb-1.0 |
| |
| use doc && dohtml doc/html/* |
| fi |
| } |
| |
| multilib_src_install_all() { |
| prune_libtool_files |
| |
| dodoc AUTHORS ChangeLog NEWS PORTING README TODO |
| |
| if use examples; then |
| insinto /usr/share/doc/${PF}/examples |
| doins examples/*.{c,h} |
| insinto /usr/share/doc/${PF}/examples/getopt |
| doins examples/getopt/*.{c,h} |
| fi |
| } |
