| # Copyright 2018 The Chromium OS Authors. All rights reserved. |
| # Distributed under the terms of the GNU General Public License v2 |
| |
| EAPI=5 |
| |
| CROS_WORKON_COMMIT="ff6532b9bafea6c0b643a545303ef3b7e9352e1a" |
| CROS_WORKON_TREE=("310a710d6c1f02a93504b35b3d8371875f253b6a" "7792a67a3de85eaf679c66a1b33c028474583862" "dc1506ef7c8cfd2c5ffd1809dac05596ec18773c") |
| CROS_WORKON_INCREMENTAL_BUILD=1 |
| CROS_WORKON_LOCALNAME="platform2" |
| CROS_WORKON_PROJECT="chromiumos/platform2" |
| CROS_WORKON_OUTOFTREE_BUILD=1 |
| CROS_WORKON_SUBTREE="common-mk dlcservice .gn" |
| |
| PLATFORM_SUBDIR="dlcservice" |
| |
| inherit cros-workon platform user |
| |
| DESCRIPTION="A D-Bus service for Downloadable Content (DLC)" |
| HOMEPAGE="https://chromium.googlesource.com/chromiumos/platform2/+/master/dlcservice/" |
| |
| LICENSE="BSD-Google" |
| SLOT="0" |
| KEYWORDS="*" |
| IUSE="" |
| |
| RDEPEND="chromeos-base/libbrillo" |
| |
| DEPEND="${RDEPEND} |
| chromeos-base/imageloader-client |
| chromeos-base/system_api |
| chromeos-base/update_engine-client" |
| |
| src_install() { |
| dosbin "${OUT}/dlcservice" |
| |
| # Seccomp policy files. |
| insinto /usr/share/policy |
| newins seccomp/dlcservice-seccomp-${ARCH}.policy \ |
| dlcservice-seccomp.policy |
| |
| # Upstart configuration |
| insinto /etc/init |
| doins dlcservice.conf |
| |
| # D-Bus configuration |
| insinto /etc/dbus-1/system.d |
| doins org.chromium.DlcService.conf |
| |
| platform_fuzzer_install "${S}"/OWNERS "${OUT}"/dlcservice_boot_slot_fuzzer \ |
| --dict "${S}"/fuzz/path.dict |
| } |
| |
| platform_pkg_test() { |
| platform_test "run" "${OUT}/dlcservice_tests" |
| } |
| |
| pkg_preinst() { |
| enewuser "dlcservice" |
| enewgroup "dlcservice" |
| } |
