| # Copyright 2018 The Chromium OS Authors. All rights reserved. |
| # Distributed under the terms of the GNU General Public License v2 |
| |
| EAPI=7 |
| |
| CROS_WORKON_COMMIT="6f9011123f3656c45bb34148673aa110a22326b3" |
| CROS_WORKON_TREE=("791c6808b4f4f5f1c484108d66ff958d65f8f1e3" "e0da5eb8dbe45cc4e72a44ebaca7260e14bc4d22" "a9708ef639f0f7929195d0f3921ebd1a12ad96bd" "e7dba8c91c1f3257c34d4a7ffff0ea2537aeb6bb") |
| CROS_WORKON_INCREMENTAL_BUILD=1 |
| CROS_WORKON_LOCALNAME="platform2" |
| CROS_WORKON_PROJECT="chromiumos/platform2" |
| CROS_WORKON_OUTOFTREE_BUILD=1 |
| # TODO(crbug.com/809389): Avoid #include-ing platform2 headers directly. |
| CROS_WORKON_SUBTREE="common-mk dlcservice metrics .gn" |
| |
| PLATFORM_SUBDIR="dlcservice" |
| |
| inherit cros-workon platform user |
| |
| DESCRIPTION="A D-Bus service for Downloadable Content (DLC)" |
| HOMEPAGE="https://chromium.googlesource.com/chromiumos/platform2/+/master/dlcservice/" |
| |
| LICENSE="BSD-Google" |
| KEYWORDS="*" |
| IUSE="fuzzer" |
| |
| RDEPEND=" |
| chromeos-base/imageloader:= |
| >=chromeos-base/metrics-0.0.1-r3152:= |
| dev-libs/protobuf:=" |
| |
| DEPEND="${RDEPEND} |
| chromeos-base/dlcservice-client:= |
| chromeos-base/imageloader-client:= |
| chromeos-base/system_api:=[fuzzer?] |
| chromeos-base/session_manager-client:= |
| chromeos-base/update_engine-client:=" |
| |
| src_install() { |
| dosbin "${OUT}/dlcservice" |
| # Technically we don't need the dlcservice_util in rootfs, but the QA team |
| # will need this to test with sample-dlc. |
| dobin "${OUT}/dlcservice_util" |
| |
| # Seccomp policy files. |
| insinto /usr/share/policy |
| newins seccomp/dlcservice-seccomp-${ARCH}.policy \ |
| dlcservice-seccomp.policy |
| |
| # Upstart configuration |
| insinto /etc/init |
| doins dlcservice.conf |
| |
| # D-Bus configuration |
| insinto /etc/dbus-1/system.d |
| doins org.chromium.DlcService.conf |
| |
| platform_fuzzer_install "${S}"/OWNERS "${OUT}"/dlcservice_boot_device_fuzzer |
| platform_fuzzer_install "${S}"/OWNERS "${OUT}"/dlcservice_boot_slot_fuzzer |
| |
| into /usr/local |
| dobin "${S}/tools/dlctool" |
| } |
| |
| platform_pkg_test() { |
| platform_test "run" "${OUT}/dlcservice_tests" |
| platform_fuzzer_test "${OUT}"/dlcservice_boot_device_fuzzer |
| platform_fuzzer_test "${OUT}"/dlcservice_boot_slot_fuzzer |
| } |
| |
| pkg_preinst() { |
| enewuser "dlcservice" |
| enewgroup "dlcservice" |
| } |
