| # Copyright 1999-2019 Gentoo Authors |
| # Distributed under the terms of the GNU General Public License v2 |
| |
| EAPI=6 |
| |
| # Note: greenlet is built-in in pypy |
| PYTHON_COMPAT=( python2_7 python3_{5,6,7} ) |
| |
| inherit distutils-r1 flag-o-matic |
| |
| DESCRIPTION="Lightweight in-process concurrent programming" |
| HOMEPAGE="https://pypi.org/project/greenlet/" |
| SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz" |
| |
| LICENSE="MIT" |
| SLOT="0" |
| KEYWORDS="*" |
| IUSE="doc" |
| |
| DEPEND=" |
| dev-python/setuptools[${PYTHON_USEDEP}] |
| doc? ( dev-python/sphinx[${PYTHON_USEDEP}] ) |
| " |
| |
| DISTUTILS_IN_SOURCE_BUILD=1 |
| |
| python_compile() { |
| if [[ ${EPYTHON} == python2.7 ]]; then |
| local CFLAGS=${CFLAGS} CXXFLAGS=${CXXFLAGS} |
| append-flags -fno-strict-aliasing |
| fi |
| |
| distutils-r1_python_compile |
| } |
| |
| python_compile_all() { |
| use doc && emake -C doc html |
| } |
| |
| python_test() { |
| "${PYTHON}" run-tests.py -n || die "Tests fail with ${EPYTHON}" |
| } |
| |
| python_install_all() { |
| use doc && local HTML_DOCS=( doc/_build/html/. ) |
| distutils-r1_python_install_all |
| } |
